Tajemnica Ctr + Shift + Enter

by Marcin

Formuły tablicoweKilka dni temu, w odpowiedzi na prośbę Piotra, przygotowałem formułę, zaznaczając, że jest to formuła tablicowa. Następnego dnia otrzymałem jednak odpowiedź z informacją, że formuła nie działa. Ostatecznie, jak łatwo zgadnąć, okazało się, że Piotr wprowadził ją jako zwykłą formułę. Nie o nieporozumienie jednak tu chodzi, a o fakt, że zostałem zapytany później, w jaki sposób uniknąć takich pomyłek?

Skąd można wiedzieć czy dana formuła jest formułą tablicową? Czy w ogóle można to wiedzieć? Co to w ogóle znaczy „formuła tablicowa”?

Doskonale zdaję sobie oczywiście sprawę, że krótki wpis na blogu na pewno nie wyczerpie tematu. Mam jednak nadzieję, że pomoże Wam przynajmniej trochę w jego zrozumieniu.

Kilka słów o „tablicowości”

Formuła (czy też funkcja) sama w sobie nie jest ani tablicowa ani nietablicowa. To Ty decydujesz, w jaki sposób Excel ma wprowadzoną formułę potraktować. „Tablicowość” jest nie tyle cechą samej formuły, ile raczej sposobem, w jaki program Excel określoną formułę „przerobi”. Akceptacja formuły przy pomocy kombinacji klawiszy Ctr+Shitf+Enter jest dla Excela zleceniem wykonania jej w sposób „tablicowy”, uwzględniając tablice przekazywane jako argumenty i otrzymywane w wynikach.

Excelowi konformiści

Część funkcji Excela domyślnie, jako argument, przyjmuje zakres komórek (tablicę) i w rezultacie zwraca pojedynczą wartość. Doskonałymi przykładami mogą być funkcje SUMA, LICZ.JEŻELI, ŚREDNIA itp. W przypadku tych funkcji nie ma żadnego znaczenia czy wprowadzisz je jako funkcje tablicowe czy nie. One i tak operują na tablicach i odnajdą się (zadziałają prawidłowo) w każdej sytuacji. Ot – tacy mali excelowi konformiści. Na szczęście honoru bronią inne funkcje, które działają zupełnie inaczej w zależności od Twoje decyzji odnośnie ich „tablicowości” (czasami nie chcą w ogóle działać). Doskonałym przykładem może być funkcja JEŻELI.

Kiedy formuła tablicowa, a kiedy zwykła?

Formuły tablicowej (wprowadzonej jako tablicowa) użyjesz wszędzie tam gdzie chcesz, aby funkcja, która „na co dzień” operuje na pojedynczych wartościach (komórkach), nagle zachowała się inaczej i przyjęła jako argument oraz zwróciła w wyniku tablicę wartości. Powróćmy do wspomnianej już funkcji JEŻELI. Jako argument przyjmuje ona wartość logiczną PRAWDA lub FAŁSZ. W klasycznej postaci

=JEŻELI ($B$7>0;”większe”;”mniejsze”)

jeżeli wartość w komórce B7 jest większa od zera, jako argument funkcja otrzyma wartość PRAWDA i w wyniku zwróci ciąg tekstowy „większe”. Gdybyś jednak chciał jednorazowo sprawdzić więcej komórek i wynik takiego sprawdzenia przekazać do jeszcze innej funkcji powinieneś posłużyć się tablicową wersją powyższej formuły.

{=JEŻELI($B$7:$B$10>0;”większe”;”mniejsze”)}

Formuły tablicowe

Jako argument funkcja przyjmuje cały zakres $B$7:$B$10. W wyniku sprawdzenia każdej komórki z zakresu, w pamięci komputera utworzona zostaje tablica

{PRAWDA;FAŁSZ;PRAWDA;PRAWDA}

Następnie, tworzona jest kolejna tablica, której wartości zależą bezpośrednio od wartości w pierwszej tablicy.Jeżeli element w pierwszej tablicy ma wartość PRAWDA, w drugiej tablicy przyjmie wartość „większe”. Jeżeli ma wartość „FAŁSZ”, element w drugiej tablicy przyjmie wartość „mniejsze”. Po tej operacji pierwsza tablica usuwana jest z pamięci komputera i ostatecznie funkcja zwraca w wyniku tablicę {„większe”, „mniejsze”, „większe”, „większe”}.

W moim przykładzie formułę tablicową wpisałem tylko do jednej komórki (jak widać na rysunku powyżej), dlatego w wyniku otrzymałem tylko jedną wartość odpowiadającą pierwszej wartości w tablicy. Wystarczy jednak wprowadzić naszą formułę tablicową do zakresu komórek, aby zobaczyć wszystkie wartości tablicy wynikowej. W przykładzie (rysunek poniżej) widać, że tablica wynikowa zawiera dokładnie cztery elementy, które wspomniałem wyżej.

Formuły tablicowe

Oczywiście tablica zwrócona przez funkcję JEŻELI może zostać przekazana dalej, „do obróbki”, jako argument dla innej funkcji.

Przykład

Wyobraźmy sobie, że chciałbyś zsumować komórki z zakresu B7:B10, ale tylko te, które są większe od zera. Oczywiście możesz użyć funkcji SUMA.JEŻELI jednak w naszym przykładzie chcemy to zrobić tylko przy pomocy formuły tablicowej. Sumując komórki naszego zakresu trzeba się będzie jakoś pozbyć wartości -32. Do funkcji SUMA musisz przekazać tablicę, w której znajdą się tylko wartości większe od zera. Wszędzie tam gdzie wartość jest mniejsza od zera, wstawimy sobie zero, które oczywiście nie wpłynie na wynik. Jak już wiesz, tymczasową tablicę z odpowiednimi wartościami możesz otrzymać przy pomocy funkcji JEŻELI. Ostatecznie, odpowiednia formuła będzie wyglądać następująco:

{=SUMA(JEŻELI($B$7:$B$10>0;$B$7:$B$10;0))}

Formuły tablicowe

W wyniku sprawdzenia każdej komórki zakresu $B$7:$B$10 (czy większa od zera) w pamięci komputera utworzona zostaje tablica {PRAWDA;FAŁSZ;PRAWDA;PRAWDA}. Następnie tworzona jest kolejna tablica. Jeżeli element w pierwszej tablicy ma wartość PRAWDA, w drugiej tablicy pojawi się wartość z odpowiedniej komórki. Jeżeli ma wartość „FAŁSZ”, element w drugiej tablicy przyjmie wartość zero. Po tej operacji pierwsza tablica usuwana jest z pamięci komputera i ostatecznie funkcja JEŻELI zwraca tablicę {23;0;15;7}. Tablica ta przekazywana jest następnie jako argument do funkcji SUMA, która, zgodnie ze swoim przeznaczeniem, zwraca sumę wszystkich elementów w tablicy. W naszym przykładzie 45. Na koniec zobacz jeszcze co się stanie jeżeli nakażesz Excelowi potraktować powyższą formułę w sposób „nietablicowy”.

Formuły tablicowe

Żadna z opisanych wyżej tablic nie zostanie w takim przypadku utworzona. Tylko jedna komórka zakresu zostanie sprawdzona (komórka w wierszu, w którym znajduje się funkcja). W naszym przypadku 15>0, więc jako pierwszy argument funkcja JEŻELI otrzyma wartość logiczną PRAWDA. Następnie do funkcji SUMA przekazany zostanie CAŁY zakres B7:B10 i w rezultacie funkcja zwróci wartość 13 (23-32+15+7). Gdyby w komórce zamiast 15 była liczba mniejsza od zera funkcja JEŻELI jako argument otrzymałaby wartość FAŁSZ i w konsekwencji do funkcji SUMA przekazana zostałaby tylko wartość zero. Nasza SUMA zwróciłaby w rezultacie także wartość zero.

Zbliżamy się do końca

Trochę się rozpisałem. Miało być tylko o rozpoznawaniu funkcji tablicowych, a skończyło się na opisie sposobu ich działania. Wydaje mi się jednak, że właściwe „rozpoznanie” zależy całkowicie od zrozumienia tego jak działają tablice w formułach. Kiedy to zrozumiesz będziesz umiał stwierdzić, że określona formuła powinna być wprowadzona jako formuła tablicowa.

Oczywiście wprowadzona jako nietablicowa może zwracać JAKIŚ wynik (o czym mogłeś się sam przed chwilą przekonać). Jeżeli jednak zrozumiesz mechanizm, będziesz widział, że taki wynik jest ZŁY i do poprawnego działania konieczne jest jednak Ctr+Shift+Enter. Jak wszystko, zrozumienie i posługiwanie się formułami tablicowymi wymaga praktyki. Warto jednak poświęcić trochę czasu na zrozumienie wszystkiego. Tablice w formułach umożliwiają bowiem rozwiązanie wielu problemów, które na pierwszy rzut oka wydawać się mogą nierozwiązywalne.

Jak zwykle zachęcam do komentowania, zadawania pytań oraz wytykania błędów.

Marcin

SUPLEMENT:

Poniżej kilka uwag, które otrzymałem od Krzysztofa (któremu, przy okazji, bardzo dziękuję), a które wydają sie doskonale uzupełniać to o czym właśnie napisałem. Oddaję więc „głos” Krzysztofowi. W jaki sposób można obejrzeć i sprawdzić wartości pośrednich wyników obliczeń, np. postaci tablic tworzonych w pamięci komputera i służących do wykonania kolejnych działań? Nic trudnego! Przykłady:

1. Uaktywnij zakres komórek z funkcją tablicową JEŻELI:

{=JEŻELI($B$7:$B$10>0;”większe”;”mniejsze”)}

Następnie, na pasku formuły zaznacz argument funkcji (jak poniżej):

{=JEŻELI($B$7:$B$10>0;”większe”;”mniejsze”)}

Wciśnij przycisk F9 (czyli Oblicz), a uzyskasz (na pasku formuły) pobrane do obliczeń wartości argumentów, jak niżej:

=JEŻELI({23\-32\15\7};”większe”;”mniejsze”)

– zapis przy użyciu ukośnika lewego oznacza, że mamy do czynienia z elementami tablicy pionowej (kolumnowej), elementy tablic wierszowych oddzielone są standardowym znakiem ; (średnik).

2. Uaktywnij zakres komórek z funkcją tablicową JEŻELI:

{=JEŻELI($B$7:$B$10>0;”większe”;”mniejsze”)}

Następnie, na pasku formuły zaznacz argument funkcji (jak poniżej, wraz z operatorem większości i wartością kryterium – „0”):

{=JEŻELI($B$7:$B$10>0;”większe”;”mniejsze”)}

Wciśnij przycisk F9, a uzyskasz obliczone wartości argumentów, jak niżej:

=JEŻELI({PRAWDA\FAŁSZ\PRAWDA\PRAWDA};”większe”;”mniejsze”)

czyli utworzoną w pamięci komputera tablicę:

{PRAWDA;FAŁSZ;PRAWDA;PRAWDA}

3. Uaktywnij komórkę z funkcją złożoną: SUMA i tablicową JEŻELI:

{=SUMA(JEŻELI($B$7:$B$10>0;$B$7:$B$10;0))}

Następnie, na pasku formuły zaznacz argument funkcji SUMA (jak poniżej):

{=SUMA(JEŻELI($B$7:$B$10>0;$B$7:$B$10;0))}

Wciśnij przycisk F9, a uzyskasz pobrane do obliczeń (sumowania) wartości argumentów, jak niżej:

=SUMA({23\0\15\7})

czyli utworzoną w pamięci komputera tablicę:

{23\0\15\7}

{ 33 comments… read them below or add one }

moonmark

Dzięki za obszerne wyjaśnienie. Bardzo mi pomogło.

Pozdrawiam

Marcin

Co oczywiście cieszy 🙂 Powodzenia w pracy z formułami tablicowymi.

Marcin

climax

wczesniej jakos nie lapalem idei funkci tablicowych, teraz czuje sie troche pewniej,
dzieki za opis

bodek

Cześć Marcin & Czytelnicy.
Zawsze podziwiałem Twoje zdolności do używania i budowy formuł tablicowych, ale że jako czas do przodu leci i człowiek się nowych rzeczy ciągle uczy, to dopiszę, że można sobie jeszcze bardziej uprościć w/w formułę pisząc ją bez JEŻELI(…), czyli dla przykładu jak powyżej wystarczy:
{=SUMA(((B7:B10)>0)*(B7:B10))}
Jest to na pierwszy rzut oka być może mniej zrozumiałe, ale po nabraniu wprawy staje się wręcz oczywiste.
Do wygenerowania wartości logicznych PRAWDA/FAŁSZ nie zawsze jest konieczność użycia funkcji JEŻELI(…), można użyć DWA RAZY (w jednej komórce) operatorów porównania, tutaj mamy („=” i „>”), czyli zapis (tablicowo):
={(B7:B10)>0}
generuje nam wynik {PRAWDA\FAŁSZ\PRAWDA\PRAWDA} (sprawdzić wciskając F9), a dalej już prosta suma z tej tablicy przemnożona przez akurat tutaj ten sam zakres komórek.
To tylko taki dodatek, do bardziej zrozumiałego dla początkujących Twojego opisu z wykorzystaniem funkcji JEŻELI(..).

Marcin

Cześć Bodek,

Co ja tu się będę rozpisywał – bardzo dziękuję za uwagi.

Marcin

norek

Czesc,
chciałem dodać do tego co wyżej napisane, ze funkcje tablicowe pozwalają na zbudowanie funkcji analogicznej do suma.jeżeli ale dla większej ilości warunków niż jeden.
Załóżmy, że mam tablicę danych z polami (kolumnami) miesiac, towar, wartosc (wszystkie kolumny zdefiniowane jako nazwy zakresów). jesli chce otrzymać sumę wartości z miesiąca 7 to mogę użyc funkcji suma.jeżeli. Jednak jeśli interesuje mnie jeszcze jaka była wartość w tym miesiącu towaru MIESO to juz musze użyć formuł tablicowych:
={suma(jeżeli(miesiac=7;jeżeli(towar=”MIESO”;wartosc;0);0))}
Ta forma wielowarunkowej sumy.jeżeli jest dla mnie podstawą w pracy – dlatego postanowilem dolożyc swoje trzy grosze

pozdrawiam
norek

kinabru

Witam Wszystkich.
Kurcze jestem gamoń i nie potrafie napisać formuły, która by sumowała komórki z funkcją JEŻELI: >> =JEŻELI(B73>1000;”???”;JEŻELI(B73>501;”1600″;JEŻELI(B73>201;”800″;JEŻELI(B73>101;”400″;JEŻELI(B73>0;”200″;JEŻELI(B73=0;”0″)))))) <<
Jest ok 20 takich komórek w słupku, ktore wyświetlaja róźne liczby w zależności od wartosci z innej komórki. Próbowalem wszystkiego i dalej nie umiem. Ktoś może wie jak napisać taką funkcję ? Będę bardzo, bardzo wdzięczny :). Prosze o odpowiedz na maila: kinabru@wp.pl. Pozdrawiam!

karimmo

Norek
Wczoraj gdzieś doczytałem jak w bardzo łatwy sposób zbudować wielo warunkową funkcję sumującą – bez definiowania tablic. Jak się okazało prościzna- wystarczy funkcja
SUMA.ILOCZYNÓW (w ang. wersji SUMPRODUCT) – przykład:
A B C D
artykuł miesiąc kto kwota
mięso marzec kowal 50
mięso marzec pawlak 60
mięso marzec kowal 80
ser marzec kowal 100
ser maj kowal 40

Ma zliczyć mięsą w marcu sprzedane przez kowala (czyli 1 i 3 wiersz danych) = 130
Czyli 3 warunki:

Wersja bez tablicy
=SUMPRODUCT((A2:A6=”mięso”)*(B2:B6=”marzec”)*(C2:C6=”kowal”)*(D2:D6))

i
wersja z tablicami:
={SUM(IF(A2:A6=”mięso”;IF(B2:B6=”marzec”;IF(C2:C6=”kowal”;D2:D6;0);0);0))} – pisałem ją chyba ze 3 razy bo za każdym razem mieszały mi się nawiasy hehe.

i wsio – kto jak woli.
(sorka, za angielszczyznę ale takiego mam offica w biurze).
Pozdrawiam,
Karimmo

karimmo

Marcin,
To samo dla Twojego przykładu:
Zamiast tablicowej wersji:

={ suma(jeżeli($B$7:$B$10>0;B7:B10;0))}

można wykorzystać funkcję suma.iloczynów (definicja tablic odbywa się już w ramach tej funkcji jeśli się nie mylę):

=suma.iloczynów(($B$7:$B$10>0)*($B$7:$B$10))

I nie trzeba pamiętać o kombinacji 3 klawiszy!!
Pozdrawiam,

S_SOB

Witam
Mam prośbę jeśli chodzi o „jeżeli” można ją zagnieździć podobno nie więcej jak 7 razy, a muszę zrobić tak aby sprawdzała mi ok.15. Czy można coś takiego zrobić?
Tabelka którą robię wygląda tak że wpisuję tekst w kom.i jeśli jest równe z tekstem w innej tabeli to ma mi podstawić z niej odpowiednie dane; cenę, wartość itp odpowiadające temu wpisowi. Może coś z tablicą?

z góry dziękuję za pomoc
Sławek

admin

Cześć,

Jak mi podeślesz (adres mail masz na stronie głównej) przykładowy plik excela to coś podpowiem. W przypadku wielu IF-ów możesz popróbować sobie także z funkcją Suma.Iloczynów

Marcin

recos

jak napisać w vba funkcje tablicowa zwracającą jakąś wartość argumentu zwiększonego o 5 oraz pomnożonego przez 5, mam takie zadanko na informatyce i niemogę sobie poradzić, z góry dziękuje za pomoc

znik

Nie wiem jak w starszych excelach, ale w 2007/XP jest funkcja suma.warunkow .
można wrzucić do 255 warunków, i obywa się bez tablic.

Buła

Rejestruję się bo natknąłem się naprawdę na bardzo fajną stronę. Przede wszystkim bardzo przydatną. Oby tak dalej !!! (a już myślałem że znam EXCEL-a przynajmniej w 5 %)

Marcin

Witam.Mam problem.Stworzyłem coś takiego (mini kalkulator druku) i działa ale potrzebuję wpisać więcej : jeżeli(oraz niż 7.Czy można coś takiego zrobić?
=JEŻELI(ORAZ(C6=”H4″;E6=”1+0″);((B17*60)/3500*(290/60)+200+40)/B17;JEŻELI(ORAZ(C6=”H4″;E6=”1P+0″);((B17*60)/3500*(315/60)+300+40)/B17;JEŻELI(ORAZ(C6=”H4″;E6=”2+0″);((B17*60)/3500*(325/60)+350+80)/B17;JEŻELI(ORAZ(C6=”H4″;E6=”3+0″);((B17*60)/3500*(340/60)+400+120)/B17;JEŻELI(ORAZ(C6=”H4″;E6=”4+0″);((B17*60)/3500*(300/60)+350+160)/B17;JEŻELI(ORAZ(C6=”H6″;E6=”1+0″);((B17*60)/4300*(390/60)+350+60)/B17;JEŻELI(ORAZ(C6=”H6″;E6=”1p+0″);((B17*60)/4300*(430/60)+500+60)/B17)))))))

admin

@Marcin

Najszybciej byloby chyba tę formułę ze zbyt dużą ilością „Jeżeli” podzielić na kilka komórek na przykład. Formuły w każdej z tych komórek sprawdzałyby część warunków, a na koniec miałbyć ostatnią komórkę, która na bazie tych cząstkowych warunków budowałąby końcowy wynik. Inna alternatywa to użycie innych funkcji (nie tylko „jeżeli”). Nic nie mogę obiecać, ale jeżeli przysłałbyś mi swój arkusz i dodatkowo dokłądnie opisał algorytm (sposób wyliczeń) to może mógłbym coś zasuregować.

Marcin

Ninek

Nareszcie zrozumiałem o co chodzi z tą formułą tablicową. Dzięki za przejrzysty opis. Z powodu tego artykułu się zarejestrowałem. 😉

sylar

Cześć
Dopiero zaczynam poznawać funkcje tablicowe i nie mogę sobie poradzić z jednym problemem. Potrzebuję zrobić funkcję, która będzie liczyła regresję z liczb spełniających podany warunek.
coś typu:
{=MEDIANA(JEŻELI($A$2:$A$11=$D1;$B$2:$B$11;””))}

tyle, że zamiast MEDIANA – REGEXPW:
=REGEXPW($A$2:$AA$11;$B$2:$B$11;B2)

pierwszy problem jest taki, że jak usiłuję w funkcję REGEXPW wrzucić funkcję JEŻELI, to wyskakuje mi „#ADR!” (nawet jeśli warunek jest wszędzie spełniony), a drugi, że nawet jeśli by mi się udało, to w w przypadku nie spełnienia warunku JEŻELI do regresji dodawany byłby „” – czyt. nieprawidłowa wartość i regresja też by się nie liczyła

jest jakiś sposób, żeby zastosować funkcje tablicowe w REGEXPW podobnie jak w przytoczonym przeze mnie przykładzie z medianą? jeśli tak, to bardzo proszę o jakiś przykład

Ziomal9416

Ciekawi mnie jak się oblicza średnią dla danego zbioru. Kurcze nie znam komendy.

mw

Marcin, studiuję Twojego bloga od jakiegoś czasu i chylę czoła za wspaniałą i bardzo przydatną w pracy lekturę! Dziękuję za Twoje poświęcenie, mam nadzieję że w imieniu także całej reszty użytkowników 🙂

Camillowski

Marcin, ten tekst o tablicach jest ogniwem którego mi od dawna brakowało! Wcześniej musiałem obchodzić problemy dziwnymi kombinacjami 🙂
Pojawił się u mnie problem…

Mam Excela 2010, i gdy spróbowałem napisać u mnie przykład z samym „JEŻELI”, to coś się posypało.

Dla kolumny z wartościami 4,-5,8,-3 Wpisałem tak jak Ty {=JEŻELI($C$4:$C$7>0;”UP”;”DOWN”)} kończąc ctrl+shift+enter.

Gdy skopiowałem formułę do dolnych komórek, wszędzie pojawił mi się „UP”.
Z suplementu dowiedziałem się jak podglądać obliczenia pośrednie i co ciekawe zauważyłem, że Excel stworzył mi tablicę w postaci WIERSZA {-4;-5;43;-67}. Poznałem to po oddzieleniu średnikiem zamiast ukośnikiem.

Co zrobić, aby Excel tworzył tablicę w postaci kolumny? 😀

Marcin

@Camillowski

Jak latwo zgadnac formula tablicowa tworzy w pamieci komputera tablice. Teraz majac taka tablice masz dwa wyjscia. Albo wykonasz na niej jakies obliczenia (np. suma wszystkich elementow, wartosc najwieksza etc) w wyniko ktorych otrzymasz JEDNA WARTOSC (liczbe). Albo wyswietlisz cala tablice w Excelu. W tym celu jednak bedziesz musial zaznaczyc odpowiednia ilosc komorek (wielkosc tablicy) i wprowadzic formule tablicowa na calym zakresie. W Twoim przykladzie, zaznacz sobie na przyklad zakres D4:D7, wprowadz te sama formule i zatwierdz tablicowo. Zobaczysz, ze przy wartosciach ujemnych pojawia sie „Down”. To co Ty prubujesz zrobic to wyswietlic cala tablice (o wymiarach czterech komorek) w jednej komorce. Jako, ze sie NIE DA, excel wyswietla tylko pierwsza wartosc, czyli UP.Zmien sobie pierwsza wartosc na ujemna to zobaczysz, ze UP zmieni sie na DOWN 🙂

NIe wiem czy jasno to opisalem. Gdyby nie – daj znac

Marcin

Camillowski

@Marcin

Dzięki, wszystko już działa 🙂
Faktycznie kwestia była w zaznaczeniu komórek i dopiero wprowadzeniu formuły. Przy czym ja po prostu chamsko kopiowałem formułę do innych komórek.
Ile to błędów trzeba się napopełniać żeby w końcu coś zaskoczyć 😀

Pozdrawiam,
Kamil

sebmio

Czy zna ktoś sposób jak w formule odwołać się nie do konkretnej wartości (np. d2=1) tylko do zakresu wartości (np. d2 posiada wartość pomiędzy 1 a 5).

zawzol

Oj…. aż się spociłem 😉
Początek kumałem, nawet zdążyłem się ucieszyć, że w końcu skumałem o co z tymi tablicami chodzi. Nawet prawie dumny byłem z siebie byłem kiedy na post noreczka wymyśliłem, że można by użyć =SUMIFS z Ex2010….
Niestety potem okazało się, że źle wymyśliłem a jeszcze potem było tylko gorzej…

No nic… w każdym razie serdecznie dziękuję za wprowadzenie do tematu – podstawy mam i teraz może być już tylko lepiej 🙂

Pozdrawiam 🙂

Anna

Czesc,
Mam pytanie, nie jestem za dobra w excelu ale w miare nie glupia:)
Czy da sie wylaczyc poszczegolne wiersze zeby excel ich nie bral pod uwage. Np. mam rozpis pomieszczen i do nich przypisana liczba okien. czy da sie „wylaczyc” tylko lazienki bo nie chce brac pod uwage akurat danych z lazienek w tym momencie?
Drugie pytanie, jesli jednemu pomieszczeniu przyporzadkuje nazwe A a innemu B, to jak moge uzyc wunkcjii if zebym w innej kolumnie w przypadku gdy jest A liczba zostala pomnozona przez 1 a w przypadku gdy jest B liczba zostala mnozona przez 2.
Przepraszam ze tak zamotalam moze troche ale siedze juz chwile nad tym i nie daje juz rady:(

Piotr

witaj,
czy możliwe jest oddzielne zdefiniowanie obszaru i uzycie go jako parametru
np: nazwa obszar o parametrach $b$7:$b$10
i potem =JEŻELIi(obszar>0; „większe”;”mniejsze”)
jak inaczej rozwiązać problem definiowania obszaru jako parametru
pozdrawiam

{=JEŻELI($B$7:$B$10>0;”większe”;”mniejsze”)}

Andrzej

Jak mogę rozwiązać następujący problem :

– w wyniku przeróżnych operacji, które nie mogłem inaczej przeprowadzić otrzymuję mi w kolumnie wynikowej (powiedzmy kolumna B) dane 0 lub 1 (tylko).
– potrzebuję teraz zaangażować jakąś funkcję excella (wyszukiwanie daty i adresu) aby podał mi dokładne adresy komórek, które zawierają wartość 1.

Problem jest w tym, że plik na którym pracuję ma już ponad 20 000 linii (obecnie ponad 17Mb) i nadal się rozrasta i założenie filtra na ten obszar praktycznie mi blokuje plik na jakieś 5-7 min
Czy jest jakaś możliwość abym (idealnie) mógł stworzyć sobie gdzieś indziej w tym pliku tabelę gdzie automatycznie pokaże mi wszystkie adresy (na ok. 20 tyś danych jest łącznie może 30-40 linii gdzie wynikowo uzyskuję pozycję 1).

Dzięki za podpowiedzi / sugestie

Jaca

Pięknie dziekuje za obszerne wyjaśnienie, dokładnie tego potrzebowałem!

Paweł

Witam!
Dzięki za stronkę!
Tworzę miesięczne raporty w których muszę wpisywać np:
„Dojazd z X do Y” a w kolumnie obok podać kilometrówkę.
Tras mam kilkanaście (Dojazd z A do B, Dojazd z C do D, Dojazd z A do D, itp.). Różne są również i kilometrówki. Jak zbudować formułę JEŻELI., by kilometrówka pojawiała się automatycznie po wpisaniu w danej komórce odpowiedniego tekstu.
Jeśli to nie skomplikowane to proszę o pomoc
Pozdrawiam
Paweł

projektowanie stron www

Fachowa notka, jak i calutka strona… Oby tak dalej!
😉 Seeya!

Roman Skurzyński

potrzebuję wstawić w kolumnie średnik za 2000 tyś numerów telefonów. Jak zrobić to w sposób masowy.
Pozdrawiam
Roman

Roman Skurzyński

oczywiście w excelu

Leave a Comment

Previous post:

Next post: